Kvėpavimo Aparatas

#include <Arduino.h>

int motorPin = 0;
int ledPin = 1;
int buttonEx1 = 2;
int buttonEx2 = 3;

#define VIBRATION_DURATION 20
#define VIBRATION_LONG_DURATION 40
#define LED_CHANGE_STEP 1

const int ledPulseDuration = (255 * LED_CHANGE_STEP) * 2;

int excercise1[] = {4, 7, 8};
int excercise2[] = {6};

void ledOn() {
  for (int i = 0; i <= 255; i++) {
    analogWrite(ledPin, i);
    delay(LED_CHANGE_STEP);
  }
}

void ledOff() {
  for (int i = 255; i >= 0; i--) {
    analogWrite(ledPin, i);
    delay(LED_CHANGE_STEP);
  }
}

void vibrateWithLedPulse() {
  digitalWrite(motorPin, HIGH);

  for (int i = 0; i <= 255; i++) {
    analogWrite(ledPin, i);
    delay(LED_CHANGE_STEP);

    if (i >= VIBRATION_DURATION) {
      digitalWrite(motorPin, LOW);
    }
  }

  for (int i = 255; i >= 0; i--) {
    analogWrite(ledPin, i);
    delay(LED_CHANGE_STEP);
  }
}

void vibrateAndSwitchOffLed() {
  digitalWrite(motorPin, HIGH);

  for (int i = 255; i >= 0; i--) {
    analogWrite(ledPin, i);
    delay(LED_CHANGE_STEP);

    if (i <= 255 - VIBRATION_DURATION) {
      digitalWrite(motorPin, LOW);
    }
  }
}

void vibrate() {
  for (int i = 0; i < 2; i++) {
    digitalWrite(motorPin, HIGH);
    delay(VIBRATION_LONG_DURATION);
    digitalWrite(motorPin, LOW);
    delay(VIBRATION_LONG_DURATION);
  }
}

void runExcercise(int ex[], int size) {
  unsigned long startAt = millis();
  unsigned long interval = 5 * 60 * 1000UL;

  bool firstRun = true;

  while (true) {
    for (int i = 0; i < size; i++) {
      if (firstRun) {
        firstRun = false;
        vibrateAndSwitchOffLed();
      } else {
        vibrateWithLedPulse();
      }
      delay((ex[i] * 1000) - ledPulseDuration);
    }

    unsigned long duration = millis() - startAt;
    if (duration >= interval) {
      break;
    }
  }

  vibrate();
  ledOn();
}

void demo() {
  while (true) {
    digitalWrite(motorPin, HIGH);

    for (int i = 0; i <= 255; i++) {
      analogWrite(ledPin, i);
      delay(LED_CHANGE_STEP);
    }

    for (int i = 255; i >= 0; i--) {
      analogWrite(ledPin, i);
      delay(LED_CHANGE_STEP);
    }

    digitalWrite(motorPin, LOW);

    delay(1000);
  }
}

void setup() {
  pinMode(motorPin, OUTPUT);
  digitalWrite(motorPin, LOW);

  pinMode(ledPin, OUTPUT);

  pinMode(buttonEx1, INPUT_PULLUP);
  pinMode(buttonEx2, INPUT_PULLUP);

  vibrate();
  ledOn();
}

void loop() {
  if (digitalRead(buttonEx1) == LOW) {
    delay(100);
    if (digitalRead(buttonEx2) == LOW) {
      demo();
      return;
    }
  }

  if (digitalRead(buttonEx1) == LOW) {
    runExcercise(excercise1, sizeof(excercise1) / sizeof(excercise1[0]));
  }

  if (digitalRead(buttonEx2) == LOW) {
    runExcercise(excercise2, sizeof(excercise2) / sizeof(excercise2[0]));
  }
}